{ config, inputs, outputs, pkgs, lib, ... }:
with pkgs; {
  imports = [
    ./hardware.nix
    ./hardware-configuration.nix # Include the results of the hardware scan.
    ../common/users/m3tam3re
    ../common/base
    ./services
  ];

  specialisation = {
    "NVIDIA".configuration = {
      boot.kernelParams = [ "nvidia.NVreg_PreserveVideoMemoryAllocations=1" ];
      system.nixos.tags = [ "NVIDIA" ];
      services.xserver.videoDrivers = [ "nvidia" ];
    };
  };
  # Bootloader.
  boot.loader.systemd-boot.enable = true;
  boot.loader.systemd-boot.memtest86.enable = true;

  boot.extraModulePackages = with config.boot.kernelPackages; [ v4l2loopback ];
  boot.kernelModules = [ "v4l2loopback" ];

  boot.extraModprobeConfig = ''
    options kvm_intel nested=1
    options kvm_intel emulate_invalid_guest_state=0
    options kvm ignore_msrs=1
    options v4l2loopback exclusive_caps=1 max_buffers=2
  '';

  networking = {
    hostName = "m3-nix";
    firewall.extraCommands =
      "iptables -t raw -A OUTPUT -p udp -m udp --dport 137 -j CT --helper netbios-ns";
    networkmanager.enable = true;
  };

  services.openssh = {
    enable = true;
    settings.PermitRootLogin = "no";
    allowSFTP = true;
  };

  services.avahi = {
    enable = true;
    nssmdns4 = true;
    publish = {
      addresses = true;
      workstation = true;
      userServices = true;
    };
  };

  programs.nix-ld.enable = true;
  programs.nix-ld.libraries = with pkgs;
    [
      # Add any missing dynamic libraries for unpackaged programs
      # here, NOT in environment.systemPackages
    ];
  programs.hyprland = {
    enable = true;
    xwayland.enable = true;
  };
  programs.steam = {
    enable = true;
    remotePlay.openFirewall = true;
    dedicatedServer.openFirewall = true;
  };
  programs.fish.enable = true;
  programs.thunar = {
    enable = true;
    plugins = with pkgs.xfce; [ thunar-archive-plugin thunar-volman ];
  };
  age = {
    secrets = {
      tailscale-key.file = ../../secrets/tailscale-key.age;
      wg-key.file = ../../secrets/wg-key.age;
      m3tam3re-secrets = {
        file = ../../secrets/m3tam3re-secrets.age;
        owner = "m3tam3re";
      };
    };
    identityPaths = [ "/root/.ssh/lkk-nix-1" ];
  };

  time.timeZone = "Europe/Berlin";
  i18n.defaultLocale = "de_DE.utf8";
  console.keyMap = "de";

  # NOTE: NIX related config

  programs.nh = {
    enable = true;
    clean.enable = true;
    clean.extraArgs = "--keep-since 4d --keep 3";
    flake = "/home/m3tam3re/projects/nix-configurations";
  };
  nix.extraOptions = ''
    experimental-features = nix-command
    keep-outputs = true
    keep-derivations = true
  '';
  nix = {
    settings = {
      experimental-features = "nix-command flakes";
      trusted-users = [ "root" "m3tam3re" ];
    };
    gc = {
      automatic = true;
      options = "--delete-older-than 30d";
    };
    optimise.automatic = true;
    registry = (lib.mapAttrs (_: flake: { inherit flake; }))
      ((lib.filterAttrs (_: lib.isType "flake")) inputs);
    nixPath = [ "/etc/nix/path" ];
  };

  environment.etc = lib.mapAttrs' (name: value: {
    name = "nix/path/${name}";
    value.source = value.flake;
  }) config.nix.registry;
  environment.systemPackages =
    [ neovim nvd nix-output-monitor wally-cli nfs-utils restic sshfs ];

  systemd.extraConfig = ''
    DefaultTimeoutStopSec=10s
  '';
  nixpkgs = {
    overlays = [
      outputs.overlays.additions
      outputs.overlays.modifications
      outputs.overlays.stable-packages
    ];
    config = {
      allowUnfree = true;
      nvidia.acceptLicense = true;
    };
  };

  # This value determines the NixOS release from which the default
  # settings for stateful data, like file locations and database versions
  # on your system were taken. It‘s perfectly fine and recommended to leavecatenate(variables, "bootdev", bootdev)
  # this value at the release version of the first install of this system.
  # Before changing this value read the documentation for this option
  # (e.g. man configuration.nix or on https://nixos.org/nixos/options.html).
  system.stateVersion = "24.05"; # Did you read the comment?
}