nix-configurations/hosts/lkk-nix-1/services/tailscale.nix

{ config, pkgs, ... }: {
  services.tailscale = {
    enable = true;
    useRoutingFeatures = "both";
  };
  networking.firewall = {
    trustedInterfaces = [ "tailscale0" ];
  };
  systemd.services.tailscale-autoconnect = {
    description = "Automatic connection to Tailscale";

    # make sure tailscale is running before trying to connect to tailscale
    after = [ "network-pre.target" "tailscale.service" ];
    wants = [ "network-pre.target" "tailscale.service" ];
    wantedBy = [ "multi-user.target" ];

    # set this service as a oneshot job
    serviceConfig = {
      Type = "oneshot";
      EnvironmentFile = "${config.age.secrets.tailscale-key.path}";
    };

    # have the job run this shell script
    script = with pkgs; ''
      # wait for tailscaled to settle
      sleep 2

      # check if we are already authenticated to tailscale
      status="$(${tailscale}/bin/tailscale status -json | ${jq}/bin/jq -r .BackendState)"
      if [ $status = "Running" ]; then # if so, then do nothing
        exit 0
      fi

      # otherwise authenticate with tailscale
      ${tailscale}/bin/tailscale up --advertise-exit-node --authkey $TAILSCALE_KEY
    '';
  };
}